How to Copy files of a certain type keeping folder structure

In this tutorial we’ll take you through copying files of a certain type while keeping their folder structure intact with the Windows command-line.

This works on all sub-folders from where the script is launched from.

The idea is to copy all files of .someextension into their own folder.

At the end of the script we’ll add a section to ask the user (you!) if you want to delete all source files that were copied.

For this example, we’ll use one of the most common formats, JPEG.

Let’s begin 😉

Part 1

As usual, we’ll start off our batch script by turning echo off, enabling our local command extensions, and making sure we are CD’d into our current folder from where this script was launched.

@ECHO OFF
@SETLOCAL enableextensions
@CD /d "%~dp0"

Part 2

Next, we’ll SET up some extension variables. These can be quickly changed for the future, and should be the only thing you change in this file after you’ve created it.
This also gives us the ability to create many “copy_ext” scripts rapidly, and with ease!

REM Frequently changed
SET TYP=JPG
SET EXT1=*.jpg
SET EXT2=*.jpeg
SET EXT3=

Part 3

Now we SET our permanent variables;

SET TTL=Copy Utility [%TYP%]
SET DIR=..\_%TYP%
SET CPR=©2008-2016 Jenkins Media. All Rights Reserved.
TITLE %TTL%

Part 4

We must make sure the target directory exists, otherwise the copy will fail.

REM Make the Target directory
MKDIR %DIR%

Part 5

Our main copy function(s)

REM Do the (x)copy
XCOPY "%EXT1%" %DIR% /S
XCOPY "%EXT2%" %DIR% /S

Part 6

Once that has completed, you can either end the script, or add these lines to add the ability to delete all source files that were copied.
This basically turns the script into a “move” script instead of copy, without using the MOVE command.

:ASK
ECHO /!\ WARNING /!\
ECHO.
ECHO ABOUT TO DELETE ALL SOURCE FILES ! ! !
SET INPUT=
SET /P INPUT=Are you sure? (Y/N) : %=%
If /I "%INPUT%"=="y" GOTO yes 
If /I "%INPUT%"=="n" GOTO no
ECHO Incorrect input & GOTO ASK
:YES
ECHO.
REM Delete source files (CAUTION! - READ BELOW)
DEL /s %EXT1%
DEL /s %EXT2%

:NO
ECHO.
ECHO MOVING TARGET DIR BACK TO SOURCE ROOT
REM Move Target dir back to Source dir (MUST COME AFTER DEL COMMAND !!!)
MOVE "%DIR%" "%~dp0"

Part 7

Let’s break that one down a bit further

SET INPUT=

This will clear our “INPUT” variable[/vc_column_text][vc_separator][vc_column_text]

SET /P INPUT=Are you sure? (Y/N) : %=%

This will display the message “Are you sure (Y/N)” and will capture whatever the user types, in this case, we just want to use “Y” or “N” to save time.

The casing isn’t important here.

Part 8

If /I "%INPUT%"=="y" GOTO yes 
If /I "%INPUT%"=="n" GOTO no

Fairly self-explanatory, the /I switch for the IF command tells CMD to treat the “equals to” as a string.

The “%INPUT%”==”y” parameter is basically saying IF %INPUT% is equal to “y” then GOTO yes.
This will jump our processing code from this position to the :YES code block detailed below.

The same is true for the “%INPUT%”==”n” parameter, except that it will jump to the :NO code block, also detailed below.

ECHO Incorrect input & GOTO ASK

This is also important to follow the 2 IF statements.

If the user typed something other than “Y” or “N“, this ECHO will be processed, and the ampersand (&) will tell CMD to “also fire this command“.

Because we have put “GOTO ASK” after the &, this will jump the processing code back to the start of asking the user (jumping back to start of :ASK code block)

Part 9

:YES
ECHO.
REM Delete source files (CAUTION! - READ BELOW)
DEL /s %EXT1%
DEL /s %EXT2%

Here we have our :YES code block. The first command “ECHO.” will print a new line to the console. This is just for ease of reading. Please note the full stop after the ECHO command, without a space. This is important. An alternative is also ECHO( but can make the code look more confusing than it needs to be.

The 2 delete commands are dangerous.

I have tried to make sure to put “CAUTION” and “WARNING” where appropriate, but the basic rule is, the DEL commands must come BEFORE you move the target folder back into the current folder (where the batch was launched from).

Otherwise, you risk deleting both the copies and the source files, and is extremely difficult to reverse this.

If you do end up in a situation where you have accidentally deleted both source and copied files because you put the DEL commands in the wrong place (e.g too late, at the end etc) then you will need to perform IMMEDIATE forensic recovery on that drive. Luckily NTFS filesystem does cache the most recently “permanently deleted” files, but it won’t last long, and the more you use the computer/disk after perma deletion, the more the cached files will deteriorate.

Part 10

Finally we end our script with some helpful ECHO messages, and safely EXIT.

:END
ECHO.
ECHO ------------------------
ECHO %TTL% %CPR%
ECHO ------------------------
ECHO Grab Completed at %TIME% - %DATE%
PAUSE
EXIT

Full code

@ECHO OFF

@SETLOCAL enableextensions
@CD /d "%~dp0"

REM Frequently changed
SET TYP=JPG
SET EXT1=*.jpg
SET EXT2=*.jpeg
SET EXT3=

REM Perma
SET TTL=Copy Utility [%TYP%]
SET DIR=..\_%TYP%
SET CPR=©2008-2016 Jenkins Media. All Rights Reserved.
TITLE %TTL%

REM Make the Target directory
MKDIR %DIR%

REM Do the (x)copy
XCOPY "%EXT1%" %DIR% /S
XCOPY "%EXT2%" %DIR% /S

:ASK
ECHO /!\ WARNING /!\
ECHO.
ECHO ABOUT TO DELETE ALL SOURCE FILES ! ! !
set INPUT=
set /P INPUT=Are you sure? (Y/N) : %=%
If /I "%INPUT%"=="y" GOTO yes 
If /I "%INPUT%"=="n" GOTO no
ECHO Incorrect input & GOTO ASK
:YES
ECHO.
REM Delete source files (CAUTION! - READ BELOW)
DEL /s %EXT1%
DEL /s %EXT2%

:NO
ECHO.
ECHO MOVING TARGET DIR BACK TO SOURCE ROOT
REM Move Target dir back to Source dir (MUST COME AFTER DEL COMMAND !!!)
MOVE "%DIR%" "%~dp0"

:END
ECHO.
ECHO ------------------------
ECHO %TTL% %CPR%
ECHO ------------------------
ECHO Grab Completed at %TIME% - %DATE%
PAUSE
EXIT